
  0 | module Libraries.Text.PrettyPrint.Prettyprinter.Util
  1 | 
  2 | import Data.List
  3 | import Libraries.Text.PrettyPrint.Prettyprinter.Doc
  4 | import Libraries.Text.PrettyPrint.Prettyprinter.Render.String
  5 | 
  6 | %default total
  7 | 
  8 | ||| Split an input into word-sized `Doc`.
  9 | export
 10 | words : String -> List (Doc ann)
 11 | words s = map pretty0 $ map pack (helper (unpack s))
 12 |   where
 13 |     helper : List Char -> List (List Char)
 14 |     helper s =
 15 |       case dropWhile isSpace s of
 16 |            [] => []
 17 |            s' => let (w, s'') = break isSpace s' in
 18 |                      w :: helper (assert_smaller s s'')
 19 | 
 20 | ||| Optionally annotate a document
 21 | export
 22 | annotateM : Maybe ann -> Doc ann -> Doc ann
 23 | annotateM = maybe id annotate
 24 | 
 25 | ||| Insert soft linebreaks between words, so that text is broken into multiple
 26 | ||| lines when it exceeds the available width.
 27 | export
 28 | reflow : String -> Doc ann
 29 | reflow = fillSep . words
 30 | 
 31 | ||| Renders a document with a certain width.
 32 | export
 33 | putDocW : Nat -> Doc ann -> IO ()
 34 | putDocW w = renderIO . layoutPretty ({ layoutPageWidth := AvailablePerLine (cast w) 1 } defaultLayoutOptions)
 35 |